【VBA】Gmailを送信する方法 CDOとアプリパスワード設定

昔作ったVBAのメール送信ツールを引っ張り出してきたら、いつの間にか使えなくなっていたので、改善方法も含めて改めてプログラムや設定方法をまとめてみました

結論から言うと、VBAからGmailを送るならCDO(Microsoft Collaboration Data Objects)を使うのが定番で、Gmail側でアプリパスワードの生成さえ済ませておけば、件名・本文・宛先・添付ファイル付きのメールをマクロから送信できます

OutlookならOutlook専用のライブラリがあるのでそちらを使ったほうが扱いやすいんですが、GmailはCDO経由で送ることになるので、今回はその方法になります

この記事ではGmail側の事前設定から、コピペでそのまま使える送信関数まで、つまづきやすいところを補足しながら解説していきます

最初にやる一番キモなGmailの事前設定

コードを書く前に、実はこのGmail側の設定が一番のキモなんですよね

ここを飛ばすと、コードが正しくてもメールは送れないので、先に片付けておきましょう

安全性の低いアプリのアクセス・・・が使用できない!?

一昔前はこの「安全性の低いアプリのアクセス」を有効化するのがGmail側の設定だったのに、いつの間にか使用できなくなっていました

(結局この部分が、昔は使えていたツールが動かなくなっていた原因でした)

と言うか、気づいていなかっただけで、しっかりGoogleから2022年5月30日より利用できなくなる事前アナウンスが出ていたのはうっかりでした

2026年現在もこの流れは変わっていなくて、個人のGmailでは「安全性の低いアプリのアクセス」はすでに廃止済みです

そのかわりに用意されたのが、次に紹介するアプリパスワードという仕組みなんですね

今は”アプリパスワード”の生成が必要

VBAのようなアプリからGmailへログインするには、普段ログインに使っている本来のパスワードではなく、アプリパスワードの生成が必要になります

2段階認証を有効にしていると、本来のパスワードはSMTPの認証で弾かれてしまうので、ここで作るアプリパスワードがログイン用のカギになるイメージです

設定するページはこちらから

https://myaccount.google.com/security

ちなみに、アプリパスワードの生成ページにはアカウント内検索だと出てこないことがあるので、その場合は https://myaccount.google.com/apppasswords に直接アクセスすると早いです

それでは実際の流れを見ていきましょう、大まかには次の3ステップです

STEP

2段階認証プロセスをオンにする

初期状態では2段階認証プロセスがオフになっているので、まずはここをオンにします

オンにするのは、次のページで“使ってみる”ボタンを押すだけです

SMSや認証アプリ、セキュリティキーといった標準の2段階認証が有効になっていればOKで、ここが済むとアプリパスワードを作れるようになります

STEP

アプリパスワードを生成する

2段階認証プロセスをオンにしたことでアプリパスワードの選択肢が増えているので、ここで設定していきます

アプリ名はアプリパスワードの名前になるだけなので、それらしい選択をすればよくて、”その他”を選ぶとフリー入力に変わります

名前を入れると“生成”ボタンが活性化するので、そのままクリックします

STEP

発行された16桁を控える

ここで表示される16桁の文字列が、いわゆるアプリパスワードです

右下の完了をクリックすると2度と表示されないので、忘れずにパスワードを控えておきましょう

もし控えそびれても、また同じ手順で新しく生成し直せばいいので、そこは安心してくださいね

ちなみに、画像は記事公開当時のものなので、今は項目名やレイアウトが少し違って見えることがあります

とはいえ「2段階認証をオン → アプリパスワードを生成 → 16桁を控える」という骨子は変わっていないので、流れさえ押さえておけば迷わないと思います

このCDO方式はいつまで使える?

長く使ってきた方式なので、これからも使えるのか気になるところですよね

そのあたりの現況だけ、簡単に注意としてまとめておきます

そうは言っても、個人利用の範囲ではまだまだ現役なので、まずは今回のCDO方式で送れるようにしておけば十分じゃないでしょうか

VBAの参照設定

続いてVBA側の準備です、参照設定で次のライブラリにチェックを入れます

Microsoft CDO for Windows 2000 Library

名前に「2000」と入っていて古そうに見えますが、これがCDO(CDO.Message)のライブラリで、今のWindowsにも標準で入っています

実際のVBAプログラム

お待たせしました、ここからが本体です

プログラムソース

件名・本文・宛先(To/Cc/Bcc)・添付ファイルまで一通り扱える送信関数です、コードの上のほうにあるmailUser と mailPass を、自分のGmailアドレスと先ほどのアプリパスワードに書き換えるだけで使えます

Function sendMail(MailSubject As String, MailBody As String, ToAddress As String, _
                    Optional CcAddress As String = vbNullString, Optional BccAddress As String = vbNullString, Optional attFile As Variant = vbNullString)

Const mailUser As String = "<Gmailのメアド>"
Const mailPass As String = "<アプリパスワード>"

Dim cdoMsg As Object: Set cdoMsg = CreateObject("CDO.Message")
Dim objFso As Object: Set objFso = CreateObject("Scripting.FileSystemObject")
Dim i As Long

With cdoMsg
    With .Configuration.Fields
        .Item("http://schemas.microsoft.com/cdo/configuration/languagecode") = "shift-jis" '---文字コード指定
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 '---外部SMTP指定
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com" '---SMTPサーバ名
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = "465" '---ポート№
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = True '---SMTP認証
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True '---SSL
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60 '---タイムアウト
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = mailUser '---ユーザー
        .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = mailPass '---パスワード
        .Update
    End With
    .Subject = MailSubject
    .TextBody = MailBody
    .TextBodyPart.Charset = "ISO-2022-JP"
    .From = mailUser
    .To = ToAddress
    .CC = CcAddress
    .BCC = BccAddress
    
    '---添付ファイルが複数（配列形式）かの分岐
    If IsArray(attFile) = True Then
        For i = LBound(attFile) To UBound(attFile)
            '---ファイルが存在してれば添付する
            If objFso.FileExists(attFile(i)) Then
                .AddAttachment attFile(i)
            End If
        Next
    Else
        '---ファイルが存在してれば添付する
        If objFso.FileExists(attFile(i)) Then
            .AddAttachment attFile(i)
        End If
    End If
    .Send
End With

Set cdoMsg = Nothing
Set objFso = Nothing
End Function

送信に関わる設定は .Configuration.Fields のあたりに集まっていて、ポイントはsmtp.gmail.com / ポート465 / SSLの3点です、ここがGmailで送るための決まりごとになります

余談ですが、参照設定をしたのになぜ”cdoMsg”のデータ型を”Object”にするのかと言うと、これならコピペするだけで(≒参照設定をしなくても)プログラムが利用できるからです

自分好みに改修したいときは、Objectから具体的な型への変更をおススメします

ざっくり説明

コード自体はコピペで動くので、ここでは使うとき用に引数だけ説明しておきます

1点だけ補足すると、添付ファイルを1つ(配列ではなく単体の文字列)で渡したときは、お使いの環境によっては添付がスキップされることがあります、確実に添付したいときは Array("C:\temp\a.pdf") のように1件でも配列で渡すと安定しますよ

呼び出すときは、必須の3つを渡すだけでも送れます、たとえばこんな感じです

'---件名・本文・宛先だけ渡すシンプルな呼び出し
Call sendMail("テスト送信", "本文です", "to@example.com")

'---添付ファイルを1つ付けて送る
Call sendMail("見積書の件", "ご確認ください", "to@example.com", , , "C:\temp\mitsumori.xlsx")

'---複数の添付ファイルは配列で渡す
Call sendMail("資料一式", "まとめてお送りします", "to@example.com", , , Array("C:\temp\a.pdf", "C:\temp\b.pdf"))

CcやBccを飛ばしたいときは、引数をカンマで詰めて空けておけば、Optionalの初期値がそのまま使われます

送信できないときに確認したいこと

実行してエラーになったり、送れているはずなのに届かなかったり、というのはよくあるので、つまづきやすいポイントをチェックリストにしておきます

• 2段階認証がオンになっているか、オフのままだとアプリパスワード自体が作れません
• mailPassに入れたのがアプリパスワードか、普段ログインに使う本来のパスワードだと認証で弾かれます
• アプリパスワードの16桁を、空白を入れずに貼り付けているか
• サーバとポートがsmtp.gmail.com / 465になっていて、SSLがTrueか
• 会社の回線などで、ポート465の通信がファイアウォールで止められていないか
• Google Workspace(法人)の場合、管理者がレガシー認証を制限していないか

個人的には、エラーが出たときはまずアプリパスワードを作り直して貼り直すのが手っ取り早い切り分けだと思います

よくある質問(FAQ)

最後に、VBAでGmailを送るときによく聞かれるところをまとめておきます

あとがき

今はAPIやWebhookでLINEなどにも通知できるので、メールの出番は減った気もしますが、メール通知もまだまだ現役で、きっとGmailが利用頻度が高いのではとまとめてみました

ちなみにVBAは、外部とのデータ連携でもけっこう活躍してくれて、APIのレスポンスを扱うVBAでJSONをパースする方法もまとめているので、あわせて読んでみてください

まずは今回のCDO方式でGmailが送れるようになれば、定型メールの自動化はだいぶ楽になるはずです、Outlook版もそのうちまとめるので、よかったらまた覗いてみてくださいね

📚 私のおすすめ本PR

VBAPythonAI・ClaudePC仕事術

Excel マクロ&VBA やさしい教科書 Office 2024/2021 Microsoft 365対応

Amazon楽天

てっとり早く確実にマスターできる Excel VBAの教科書 改訂新版

Amazon楽天

Excel マクロ/VBA 今日から使える業務の自動化入門

Amazon楽天

VBAエキスパート公式テキスト Excel VBAベーシック

Amazon楽天

［最速入門］ChatGPTに任せる Excelマクロ&VBA

Amazon楽天

退屈なことはPythonにやらせよう 第3版

Amazon楽天

シゴトがはかどる Python自動処理の教科書

Amazon楽天

もっとシゴトがはかどる Python×Excel×AI 業務自動化の教科書

Amazon楽天

Python2年生 スクレイピングのしくみ 第2版

Amazon楽天

スッキリわかるPython入門 第2版

Amazon楽天

実践Claude Code入門

Amazon楽天

Claude CodeによるAI駆動開発入門

Amazon楽天

開発効率をアップする! Claude Code 実用入門

Amazon楽天

Microsoft 365 Copilot踏み込み活用術

Amazon楽天

できるClaude & Claude Cowork

Amazon楽天

できる人のパソコン仕事術 なんと効率10倍!

Amazon楽天

できるWindows 11パーフェクトブック 困った!&便利ワザ大全 改訂3版

Amazon楽天

できるポケット 時短の王道 ショートカットキー全事典 改訂4版

Amazon楽天

ビジュアル ショートカットキー時短ワザ事典

Amazon楽天

取り急ぎ、パソコン仕事の基本だけ教えてください！

Amazon楽天

ジャンルごとに私のおすすめからランダムで5冊を表示しています